
! Copyright (C) 2021 J. K. Dewhurst, S. Sharma and E. K. U. Gross.
! This file is distributed under the terms of the GNU General Public License.
! See the file COPYING for license details.

subroutine getvnorm(ik,vnorm)
use modmain
implicit none
! arguments
integer, intent(in) :: ik
real(8), intent(out) :: vnorm(nstsv)
! local variables
integer recl,nstsv_
real(8) vkl_(3),t1
! find the record length
inquire(iolength=recl) vkl_,nstsv_,vnorm
!$OMP CRITICAL(u324)
open(324,file='VNORM.OUT',form='UNFORMATTED',access='DIRECT',recl=recl)
read(324,rec=ik) vkl_,nstsv_,vnorm
!$OMP END CRITICAL(u324)
t1=abs(vkl(1,ik)-vkl_(1))+abs(vkl(2,ik)-vkl_(2))+abs(vkl(3,ik)-vkl_(3))
if (t1.gt.epslat) then
  write(*,*)
  write(*,'("Error(getvnorm): differing vectors for k-point ",I8)') ik
  write(*,'(" current   : ",3G18.10)') vkl(:,ik)
  write(*,'(" VNORM.OUT : ",3G18.10)') vkl_
  write(*,*)
  stop
end if
if (nstsv.ne.nstsv_) then
  write(*,*)
  write(*,'("Error(getvnorm): differing nstsv for k-point ",I8)') ik
  write(*,'(" current   : ",I8)') nstsv
  write(*,'(" VNORM.OUT : ",I8)') nstsv_
  write(*,*)
  stop
end if
end subroutine

