include(doc/doc.pro)

QT += webkit
SOURCES += source-highlight-ide.cpp \
    main.cpp \
    sourcehighlightideframe.cpp \
    filechooserframe.cpp \
    debuggerthread.cpp \
    statusbarframe.cpp \
    findreplaceform.cpp \
    findreplacedialog.cpp \
    mainwindow.cpp \
    assistant.cpp \
    customhelpform.cpp
HEADERS += source-highlight-ide.h \
    sourcehighlightideframe.h \
    filechooserframe.h \
    debuggerthread.h \
    stepconditionvariable.h \
    statusbarframe.h \
    findreplaceform.h \
    findreplacedialog.h \
    findreplace_global.h \
    mainwindow.h \
    assistant.h \
    customhelpform.h
TEMPLATE = app
CONFIG += warn_on \
    thread \
    qt
TARGET = source-highlight-ide

DEPENDPATH += .
DESTDIR = bin

DEFINES += SOURCEDIR=\\\"$$PWD\\\"

target.path = /bin
INSTALLS += target

RESOURCES = application.qrc

isEmpty(NO_PKGCONFIG) {
    CONFIG += link_pkgconfig
    PKGCONFIG += source-highlight-qt4
}

!isEmpty(SOURCE_HIGHLIGHT_QT_LIB) {
    ADDITIONAL_LIBRARIES += -l$$SOURCE_HIGHLIGHT_QT_LIB
}

!isEmpty(SOURCE_HIGHLIGHT_LIB) {
    ADDITIONAL_LIBRARIES += -l$$SOURCE_HIGHLIGHT_LIB
}

!isEmpty(BOOST_REGEX) {
    ADDITIONAL_LIBRARIES += -l$$BOOST_REGEX
}

LIBS += $$ADDITIONAL_LIBRARIES

DISTFILES += *.xpm
VERSION = 1.0.0
FORMS += sourcehighlightideframe.ui \
    filechooserframe.ui \
    sourcehighlightidewindow.ui \
    statusbarframe.ui \
    findreplaceform.ui \
    findreplacedialog.ui \
    mainwindow.ui \
    customhelpform.ui

OTHER_FILES = COPYING ReadMe TODO.txt
